Manchmal ist es nötig, auf Fremdprogramme zuzugreifen, da Sie nicht über das nötige Wissen oder die Möglichkeiten verfügen, um seine Funktionen nachzubilden. Oder wollen Sie einfach nur ein Infofenster anzeigen, das es auch als eigenständige Exe gibt? Egal ob DOS-Packprogramm, Windows-Netzwerkmonitor oder Infobox: Im folgenden wird Ihnen gezeigt, wie Sie solche Fremdanwendungen starten und ihr Programm dazu bringen, solange zu warten, bis diese beendet wurde.

Ihre Bewertung:   1 2 3 4 5

Bewertung dieses Tipps:

(bewertet von insgesamt 26 Besuchern)

Um diese API-Funktionen in Ihren eigenen Projekten verwenden zu können, müssen Sie zuerst im Kopf eines Moduls oder einer Form deklariert werden. Zusätzlich werden noch einige Konstanten, Typdeklarationen und die letzendliche Subroutine benötigt. Ich empfehle Ihnen, diese Angaben in einem Modul zu plazieren, da die Routine dann später im gesamten Projekt zur Verfügung stehen wird.

Private Type STARTUPINFO
   cb As Long
   lpReserved As String
   lpDesktop As String
   lpTitle As String
   dwX As Long
   dwY As Long
   dwXSize As Long
   dwYSize As Long
   dwXCountChars As Long
   dwYCountChars As Long
   dwFillAttribute As Long
   dwFlags As Long
   wShowWindow As Integer
   cbReserved2 As Integer
   lpReserved2 As Long
   hStdInput As Long
   hStdOutput As Long
   hStdError As Long
End Type

Private Type PROCESS_INFORMATION
   hProcess As Long
   hThread As Long
   dwProcessID As Long
   dwThreadID As Long
End Type

Private Declare Function WaitForSingleObject Lib "kernel32" (ByVal hHandle As Long, ByVal dwMilliseconds As Long) As Long
Private Const INFINITE = -1&

Private Declare Function CreateProcessA Lib "kernel32" (ByVal lpApplicationName As Long, ByVal lpCommandLine As String, ByVal lpProcessAttributes As Long, ByVal lpThreadAttributes As Long, ByVal bInheritHandles As Long, ByVal dwCreationFlags As Long, ByVal lpEnvironment As Long, ByVal lpCurrentDirectory As Long, lpStartupInfo As STARTUPINFO, lpProcessInformation As PROCESS_INFORMATION) As Long
Private Const NORMAL_PRIORITY_CLASS = &H20&

Private Declare Function CloseHandle Lib "kernel32" (ByVal hObject As Long) As Long


Sub ShellAndWait(ByVal Filename As String)
   Dim RetVal As Long
   Dim proc As PROCESS_INFORMATION
   Dim StartInf As STARTUPINFO
   
   StartInf.cb = Len(StartInf)
   
   'Angegebenes Programm starten
   RetVal = CreateProcessA(0&, Filename, 0&, 0&, 1&, NORMAL_PRIORITY_CLASS, 0&, 0&, StartInf, proc)

   'Das eigene Programm anhalten, bis das fremde beendet wurde
   RetVal = WaitForSingleObject(proc.hProcess, INFINITE)
   RetVal = CloseHandle(proc.hProcess)
End Sub

Der Aufruf der Routine dürfte sich eigentlich von selbst erklären, hier ein jedoch noch einmal ein kleines Beispiel:

MsgBox "Bitte editieren Sie die Datei."

'Windows Editor mit der Datei "Autoexec.bat" starten
ShellAndWait "C:\Windows\Notepad.exe C:\Autoexec.bat"

MsgBox "Die Änderungen der Datei wurden erfolgreich übernommen."

---

Quellen: SHADOWare.de Letzte Änderung: 29.10.00

©2000 by SHADOWare, Thomas Bachem